Vielleicht so, aber Angaben ohne Gewähr!
Code:
             PGM                                                       
             DCL        VAR(&MSGQ)    TYPE(*CHAR) LEN(10)              
             DCL        VAR(&MSGQLIB) TYPE(*CHAR) LEN(10)              
             DCL        VAR(&KEYVAR)  TYPE(*CHAR) LEN(4)               
             DCL        VAR(&SENDER)  TYPE(*CHAR) LEN(80)              
             DCL        VAR(&DATTIM)  TYPE(*CHAR) LEN(13)              
             DCL        VAR(&DATE)    TYPE(*CHAR) LEN(7)               
                                                                       
             MONMSG     MSGID(CPF0000) EXEC(GOTO CMDLBL(ENDPGM))       
                                                                       
             CHGVAR     VAR(&MSGQ)    VALUE(QSYSOPR)                   
             CHGVAR     VAR(&MSGQLIB) VALUE(*LIBL)                     
             CHGVAR     VAR(&DATE)    VALUE('1080918') /*CYYMMTT*/     
                                                                       
 LOOP:       RCVMSG     MSGQ(&MSGQLIB/&MSGQ) MSGTYPE(*FIRST) +         
                          RMV(*NO) KEYVAR(&KEYVAR) SENDER(&SENDER) +   
                          SENDERFMT(*SHORT)                            
                                                                       
             CHGVAR     VAR(&DATTIM) VALUE(%SST(&SENDER 43 13))        
                                                                       
             IF         COND(&DATTIM *GE &DATE *OR +                   
                             &DATTIM *EQ ' ') THEN(GOTO CMDLBL(ENDPGM))
                                                                       
             RMVMSG     MSGQ(&MSGQLIB/&MSGQ) MSGKEY(&KEYVAR) +         
                          CLEAR(*BYKEY)                                
                                                                       
             GOTO       CMDLBL(LOOP)                                   
 ENDPGM:     ENDPGM