Data-Structure-Array

[Christian.Hesse]

Hallo!

Ich habe ein Programm, in dem ich folgende Datenstruktur definiert habe:

DassemblyLineCustomerDS...                           
D                 DS                  QUALIFIED      
D abbreviation                        LIKE(ALICAL)   
D name                          35A                  
D maxBuffer                     10U 0                
D lastSequenceReceived...                            
D                                     LIKE(CSEQSC)   
D lastSequencePrinted...                             
D                                     LIKE(CSEQSC)   
D lastSequenceStarted...                             
D                                     LIKE(CSEQSC)   
D lastSequenceTerminated...                          
D                                     LIKE(CSEQSC)   
D lastSequenceDelivered...                           
D                                     LIKE(CSEQSC)   
D unsequencedOrdersCount...                          
D                               10U 0                
D inProductionCount...                               
D                               10U 0                
D bufferCustomerLineCount...                         
D                               10U 0     
D openOrdersCount...                      
D                               10U 0     
D                                         
DassemblyLinesCustomer...                                          
D                 S                   LIKE(assemblyLineCustomerDS) 
D                                     DIM(10)

Jetzt greife ich auf das Array von Data Structures wie folgt zu:

/free
.
.
.
       assemblyLinesCustomer(assemblyLineCustomerCount). 
           abbreviation = ALICAL;                        
.
.
.
/end-free

und bekomme beim Compilieren die Fehlermeldungen:

*RNF7030 30 302 012900 The name or indicator ABBREVI... is not defined.
*RNF7503 30 302 012900 Expression contains an operand that is not defined.

Wo ist dabei mein Denkfehler? Ich kann Prozedur-Aufrufe ja auch einfach umbrechen, darf ich das etwa mit Zugriffen auf Arrays und Datenstrukturen nicht?

Vielen herzlichen Dank für eure Mühe schon im Voraus und ein schönes Wochenende

Christian

[Fuerchau]

Auch hier gilt die Fortsetzungslogic:

assemblyLinesCustomer(assemblyLineCustomer...
Count).abbreviation = ALICAL;

[B.Hauser]

Hallo,

das Problem ist nicht das Umbrechen, sondern die Definition des Datenstruktur-Arrays, d.h. Du hast kein Datenstruktur-Array, sondern lediglich eine Feldgruppe definiert.

Die Definition für ein Datenstrukture-Array müsste wie folgt aussehen:

D assemblyLinesCustomer...                                          
D                 DS                  LIKEDS(assemblyLineCustomerDS)
D                                     DIM(10) 

Birgitta

[Christian.Hesse]

Hallo!

Vielen herzlichen Dank! Es war tatsächlich die Definition der Datenstruktur gewesen. Jetzt tut es endlich.

Gut aber zu wissen, daß ich im Freiformat auch mit ... Namen fortsetzen kann.

Vielen Dank und viele Grüße

Christian

[B.Hauser]

Gut aber zu wissen, daß ich im Freiformat auch mit ... Namen fortsetzen kann.

Wäre traurig, wenn das nur im fixed Format ginge, besonders, da Variablen-Namen bis 4.096 Zeichen lang sein können.

Birgitta