PHP-Code:
         ctl-opt main(main) dftactgrp(*no) option(*nounref);
      //------------------------------------------------------------------//
      //                                                                  //
      // GetHostByName                                                    //
      //                                                                  //
      //-----------------                                                 //
      // R.Ross 12.2016 *                                                 //
      //------------------------------------------------------------------//
      // Get Host by Name                                                 //
      //------------------------------------------------------------------//

         dcl-pr gethost      pointer extproc('gethostbyname');
                 ##host      pointer value options(*string);
         end-pr;

      //------------------------------------------------------------------//
      // Transform Internet Address to a dottet decimal Format            //
      //------------------------------------------------------------------//

         dcl-pr transform    pointer extproc('inet_ntoa');
                 ##address   uns(10) value;
         end-pr;

      //------------------------------------------------------------------//
      // Array - HostEntry                                                //
      //------------------------------------------------------------------//

         dcl-s   d#host_p    pointer;

         dcl-ds  dshost      based(d#host_p);
                  d#name     pointer;
                  d#alias    pointer;
                  d#addrtyp  int(10);
                  d#length   int(10);
                  d#addrlist pointer;
         end-ds;

         dcl-s   d#addr_p    pointer based(d#addrlist);
         dcl-s   d#hostaddr  uns(10) based(d#addr_p);

      //------------------------------------------------------------------//
      // Variablen                                                        //
      //------------------------------------------------------------------//

         dcl-s   h#host      char(32);
         dcl-s   h#ipchar    char(15);
         dcl-s   h#ip        uns(10);

      //------------------------------------------------------------------//
      // Main                                                             //
      //------------------------------------------------------------------//
         dcl-proc main;

           h#host  = 'www.web.de';

           d#host_p = gethost(%trim(h#host));

           if d#host_p <> *null;
              h#ip     = d#hostaddr;
              h#ipchar = %str(transform(h#ip));
           endif;

         end-proc;
      //------------------------------------------------------------------//