AS400 - Daten als txt exportieren

[RobertMack]

Wie "fett" ist denn Dein Word-Dokument?

Wenn Du es mit ^Platzhaltern versiehst und als Open-Office-XML ins IFS stellst, kannst Du im RPG mischen und ggf. auch gleich verschicken...

ääähm, beim zweite Lesen sieht es eher danach aus als wolltest Du einfach nur die RPG-Quelle übertragen...

[svente]

Danke für den schnelle Tip. Kannst du mir noch sagen wo ich das im Navigator mache. Habe diese Funktion noch nie genutzt...

Klar geht das,
am besten mit der Funktion Daten übertragen im Navigator. Einfach als Quelle die SRC-File und das Member auswählen, Ort angeben wo die Datei hin soll und als Datenart Textdatei angeben. (geht auch mit ftp, dann musst du aber die IP Adresse deines Rechners/Laufwerks kennen).
Klaus.

evtl. die CCSID angeben.

[RobertMack]

Ich arbeite zu 90% noch in der "Grünen" Oberfläche.

Kleinster gemeinsamer Nenner aller Maschinen ;- )

PDM-Option:

EX    ? EX MEMBER(&N) FILE(&F) LIB(&L) 

CMD EX

             CMD        PROMPT('QUELLEN-TEILDATEI EXPORTIEREN')      
             PARM       KWD(MEMBER) TYPE(*CHAR) LEN(10) MIN(1) +     
                          MAX(1) CHOICE('NAME') +                    
                          PROMPT('QUELLEN-TEILDATEI')                
             PARM       KWD(FILE) TYPE(*CHAR) LEN(10) DFT(QRPGSRC) + 
                          MIN(0) MAX(1) CHOICE('QRPGSRC, QCLSRC +    
                          ...') PROMPT('PHYSISCHE DATEI')            
             PARM       KWD(LIB) TYPE(*CHAR) LEN(10) DFT(*LIBL) +    
                          MIN(0) MAX(1) CHOICE('NAME, *CURLIB, +     
                          *LIBL') PROMPT('BIBLIOTHEK') 

CLP EXPSRC

             PGM        PARM(&MEMBER &FILE &LIB)

             DCL        VAR(&FILE) TYPE(*CHAR) LEN(10)
             DCL        VAR(&MEMBER) TYPE(*CHAR) LEN(10)
             DCL        VAR(&LIB) TYPE(*CHAR) LEN(10)

             DCL        VAR(&USER) TYPE(*CHAR) LEN(10)
             DCL        VAR(&IFSDIR) TYPE(*CHAR) LEN(128)
             DCL        VAR(&FROM) TYPE(*CHAR) LEN(128)
             DCL        VAR(&TO) TYPE(*CHAR) LEN(128)
             DCL        VAR(&PCDIR) TYPE(*CHAR) LEN(128)
             DCL        VAR(&C) TYPE(*CHAR) LEN(128)
             DCL        VAR(&F) TYPE(*CHAR) LEN(128)
             DCL        VAR(&STRING) TYPE(*CHAR) LEN(128)

             RTVJOBA    USER(&USER)

             CHGVAR VAR(&IFSDIR) VALUE('/USERTEMP/' *CAT &USER)
             MD         DIR(&IFSDIR) DTAAUT(*RWX) OBJAUT(*ALL)
             MONMSG     MSGID(CPF0000)

             CHGVAR     VAR(&FROM) VALUE('/QSYS.LIB/' *TCAT &LIB +
                          *TCAT '.LIB/' *TCAT &FILE *TCAT '.FILE/' +
                          *TCAT &MEMBER *TCAT '.MBR')

             CHGVAR     VAR(&TO) VALUE(&IFSDIR *TCAT '/' *TCAT +
                          &MEMBER *TCAT '.TXT')

             CPYTOSTMF  FROMMBR(&FROM) TOSTMF(&TO) STMFOPT(*REPLACE) +
                          STMFCODPAG(*PCASCII)
             CHGAUT     OBJ(&TO) USER(*PUBLIC) DTAAUT(*RWX) +
                          OBJAUT(*ALL)

 SEND2PC:    STRPCO
             MONMSG     MSGID(IWS4010)
             MONMSG     MSGID(CPF0000)

 BAT:        CHGVAR VAR(&PCDIR) VALUE('%temp%\AS400IFS')
             CHGVAR VAR(&C) VALUE('cmd.exe /c echo')
             CHGVAR VAR(&F) VALUE('%temp%\AS400IFS.BAT')

             STRPCCMD PCCMD(&C *BCAT '@ECHO OFF' *BCAT '>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'mkdir %temp%\AS400IFS >>' *BCAT &F)

             STRPCCMD PCCMD(&C *BCAT 'cd.. >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'cd.. >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'cd.. >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'cd %temp% >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'ftp -s:AS400IFS.FTP.CMD >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'del %temp%\AS400IFS.FTP.CMD >>' *BCAT &F)

 FTP:        CHGVAR VAR(&C) VALUE('Cmd.exe /c echo')
             CHGVAR VAR(&F) VALUE('%temp%\AS400IFS.FTP.CMD')
             STRPCCMD PCCMD(&C *BCAT 'open xxx.xxx.xxx.xxx >>' *BCAT &F)    
             STRPCCMD PCCMD(&C *BCAT 'UsrPrf >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'Pwd >>' *BCAT &F)

             STRPCCMD PCCMD(&C *BCAT 'lcd AS400IFS' *BCAT '>>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'get /USERTEMP/' *TCAT &USER *TCAT +
              '/' *TCAT &MEMBER *TCAT '.TXT >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'prompt >>' *BCAT &F)

             STRPCCMD PCCMD(&C *BCAT 'disconnect >>' *BCAT &F)
             STRPCCMD PCCMD(&C *BCAT 'bye >>' *BCAT &F)

 EXE:        STRPCCMD PCCMD('cmd.exe /c %temp%\AS400IFS.BAT')

             CHGVAR     VAR(&STRING) VALUE('cmd.exe /c start +
                          NOTEPAD %temp%\AS400IFS\' *TCAT +
                          &MEMBER *TCAT '.TXT')

             STRPCCMD PCCMD(&STRING)

 ENDE:       ENDPGM 

Zusätzlicher Tip: eigenes, eingeschränktes UsrPrf für solche Zugriffe

[K_Tippi]

Schau mal in deiner "Grünen Oberfläche" da gibt es oben evtl. den Punkt Aktionen und dort Daten übertragen.