Alt aber immer noch praktisch:

PHP-Code:
     HDEBUG DECEDIT('0,') DATEDIT(*DMY.)

     FFTPINP    O  A F  120        DISK    USROPN

     D                 DS
     D Days                    1     14    INZ('modimidofrsaso')
     D Day                     1     14    DIM(7)
     D DoW             S              1  0

     C/EXEC SQL SET :DoW = DayOfWeek_ISO(current_date)
     C/END-EXEC

     C     *DTAARA       DEFINE    SICHERUNG     SYSNAM            8
     C                   IN        SYSNAM
     C                   SELECT
     C                   WHEN      SYSNAM = 'TEST '
     C                   EXSR      SICHTEST                                     
     C                   WHEN      SYSNAM = 'PROD '
     C                   EXSR      SICHPROD                                     
     C                   OTHER
     C                   ENDSL
     C                   EVAL      *INLR = *ON

     C     SICHTEST      BEGSR
     C                   EVAL      CMD = 'CLRSAVF MySAVF'
     C                   EXSR      RUNCMD
     C                   EVAL      CMD = 'SAVOBJ OBJ(*ALL) LIB(MyLIB) ' +
     C                             'DEV(*SAVF) OBJTYPE(*FILE) SAVF(QGPL/MySAVF)'
     C                   EXSR      RUNCMD
     C                   EVAL      CMD = 'CRTSRCPF QTEMP/FTPINP MBR(INPUT) ' +
     C                                   'RCDLEN(120)'
     C                   EXSR      RUNCMD
     C   50              EVAL      CMD = 'CLRPFM QTEMP/FTPINP'
     C   50              EXSR      RUNCMD
     C   50              LEAVESR
     C                   EVAL      CMD = 'OVRDBF FILE(INPUT) TOFILE(QTEMP/' +
     C                                   'FTPINP)'
     C                   EXSR      RUNCMD
     C   50              LEAVESR
     C                   OPEN      FTPINP                               50
     C   50              LEAVESR
     C                   MOVE      *BLANK        SRCLINE         108
     C                   EVAL      SRCLINE = 'prf pwd'
     C                   EXCEPT    SRCADD
     C                   EVAL      SRCLINE = 'cd backup'
     C                   EXCEPT    SRCADD
     C                   EVAL      SRCLINE = 'mkdir testsystem'
     C                   EXCEPT    SRCADD
     C                   EVAL      SRCLINE = 'cd testsystem'
     C                   EXCEPT    SRCADD
     C                   EVAL      SRCLINE = 'bin'
     C                   EXCEPT    SRCADD
     C                   EVAL      SRCLINE = 'put MySAVF MySAVF' +
     C                                        Day(DoW) + '.savf'
     C                   EXCEPT    SRCADD
     C                   EVAL      SRCLINE = 'close'
     C                   EXCEPT    SRCADD
     C                   EVAL      SRCLINE = 'quit'
     C                   EXCEPT    SRCADD
     C                   CLOSE     FTPINP
     C                   EVAL      CMD = 'FTP RMTSYS(nnn.nnn.nnn.nnn)'
     C                   EXSR      RUNCMD
     C                   ENDSR

     C     SICHPROD      BEGSR
     C                   ENDSR

     C     RUNCMD        BEGSR
     C                   CALL      'QCMDEXC'                            50
     C                   PARM                    CMD             160
     C                   PARM      160           CMDLEN           15 5
     C                   ENDSR

     OFTPINP    EADD         SRCADD
     O                       SRCLINE        B   120